わいえむねっと

use CGI;

my $q = new CGI;

foreach my $key($q->param)
{
    foreach($q->param($key))
    {
        print "param($key): $_\n";
    }
}

my  $i = 0;
foreach(@ARGV)
{
    print "\$ARGV[$i]: $_\n";
    $i++;
}

# <!--#include virtual="foo.pl?foo:bar+baz:qux"-->
# param(keywords): foo:bar
# param(keywords): baz:qux
# $ARGV[0]: foo:bar
# $ARGV[1]: baz:qux

# <!--#include virtual="foo.pl?foo:bar baz:qux"-->
# param(keywords): foo:bar
# param(keywords): baz:qux
# $ARGV[0]: foo:bar baz:qux

# <!--#include virtual="foo.pl?foo:bar&baz:qux"-->
# param(foo): bar baz=qux

# <!--#include virtual="foo.pl?foo=bar+baz=qux"-->
# param(foo): bar baz=qux

# <!--#include virtual="foo.pl?foo=bar baz=qux"-->
# param(foo): bar baz=qux

# <!--#include virtual="foo.pl?foo=bar&baz=qux"-->
# param(foo): bar
# param(baz): qux

2010/05/21 17:56:38

2010/05/21 18:08:23

モジュールの場合

package Foo;
use base qw(Exporter);
our @EXPORT_OK = qw(foo);

sub foo
{
    print $_[0];
}

1;

use Foo qw(foo);

foo 'foo';
#foo

とりあえずモジュールをねじ込む

package Foo;
use base qw(Exporter);
our @EXPORT_OK = qw(foo);

sub foo
{
    print $_[0];
}

package main;

foo 'foo';
#String found where operator expected at foo.pl line 12, near "foo 'foo'"
#    (Do you need to predeclare foo?)
#syntax error at foo.pl line 12, near "foo 'foo'"
#Execution of foo.pl aborted due to compilation errors.

Foo::foo 'foo';
#foo

とりあえずimportしてみる

package Foo;
use base qw(Exporter);
our @EXPORT_OK = qw(foo);

sub foo
{
    print $_[0];
}

package main;
BEGIN {import Foo qw(foo)}

foo 'foo';
#"foo" is not exported by the Foo module
#Can't continue after import errors at foo.pl line 11
#BEGIN failed--compilation aborted at foo.pl line 11.

タイミングを前にずらしてみる

package Foo;
use base qw(Exporter);
BEGIN {our @EXPORT_OK = qw(foo)}

sub foo
{
    print $_[0];
}

package main;
BEGIN {import Foo qw(foo)}

foo 'foo';
#foo

タイミングを後ろにずらしてみる

package Foo;
use base qw(Exporter);
our @EXPORT_OK = qw(foo);

sub foo
{
    print $_[0];
}

package main;
import Foo qw(foo);

foo 'foo';
#String found where operator expected at foo.pl line 13, near "foo 'foo'"
#    (Do you need to predeclare foo?)
#syntax error at foo.pl line 13, near "foo 'foo'"
#Execution of foo.pl aborted due to compilation errors.

eval "foo 'foo'";
#foo

宣言してお茶を濁してみる

package Foo;
use base qw(Exporter);
our @EXPORT_OK = qw(foo);

sub foo
{
    print $_[0];
}

package main;
sub foo;
import Foo qw(foo);

foo 'foo';
#foo

Exporterのことは忘れてシンボルテーブルに自前でねじ込んでみる

package Foo;

sub import
{
    my $pkg = shift @_;
    *{caller(0)."::$_"} = \&{$pkg."::$_"} foreach @_;
}

sub foo
{
    print $_[0];
}

package main;
BEGIN {import Foo qw(foo)}

foo 'foo';
#foo

2010/05/19 18:29:58

2010/05/19 23:12:18